home *** CD-ROM | disk | FTP | other *** search
/ Aminet 40 / Aminet 40 (2000)(Schatztruhe)[!][Dec 2000].iso / Aminet / misc / emu / msh-156.lha / han / hancrtso.a < prev    next >
Text File  |  1996-12-22  |  9KB  |  382 lines
  1. ; $Id: hancrtso.a,v 1.56 1996/12/22 00:22:33 Rhialto Rel $
  2. ; $Log: hancrtso.a,v $
  3. ; Revision 1.56  1996/12/22  00:22:33  Rhialto
  4. ; Add private BeginIO().
  5. ;
  6. ; Revision 1.55  1993/12/30  23:02:45  Rhialto
  7. ; *** empty log message ***
  8. ;
  9. ; Revision 1.54  1993/06/24  05:12:49  Rhialto
  10. ; DICE 2.07.54R.
  11. ;
  12. ; Revision 1.53  92/10/25  02:21:25  Rhialto
  13. ; No change.
  14. ; 
  15. ; Revision 1.51  92/04/17  15:34:37  Rhialto
  16. ; Freeze for MAXON.
  17. ; 
  18. ; Revision 1.46  91/10/06  18:25:52  Rhialto
  19. ;
  20. ; Freeze for MAXON
  21. ;
  22. ; Revision 1.43  91/09/28  01:46:54  Rhialto
  23. ; Create regargs entrypoints for byte swap routines.
  24. ;
  25. ; Revision 1.42  91/06/14  00:07:56  Rhialto
  26. ; DICE conversion
  27. ;
  28. resident    equ 1    ; Do we handle RESIDENT (== pure) code?
  29. ;        near a4 ; for A68k 2.7.1: also needs -m32766 for offset
  30.         ;   C.A
  31.         ;
  32.         ;   (c)Copyright 1990, Matthew Dillon, All Rights Reserved
  33.         ;
  34.         ;   Amiga startup code for non-resident and resident DCC
  35.         ;   programs.
  36.         ;
  37.         ;   Modified for use with a DOS handler.
  38.         ;
  39.         ;   DLINK:
  40.         ;
  41.         ;   * __BSS_LEN   : # long wrds of bss (occurs after DATA)
  42.         ;   * __DATA_LEN  : # long wrds of initialized data to copy (if resident)
  43.         ;   * __DATA_BAS  : base of data (read only if resident)
  44.         ;   * __RESIDENT  : is this code residentable?    If this variable
  45.         ;            is set then there are no absolute data/bss
  46.         ;            references except __DATA_BAS and there is
  47.         ;            NO BSS MEMORY ALLOCATED AFTER THE DATA
  48.         ;            SECTION.
  49.         ;
  50.         ;            If this variable is not set then absolute
  51.         ;            references refer to the same storage as
  52.         ;            A4 relative accesses and uninitialized
  53.         ;            BSS space exists just after the data section.
  54.         ;
  55.         ;            Note that in the large-data model + fragmented
  56.         ;            sections, there are usually real BSS hunks
  57.         ;            floating about that have been zerod by
  58.         ;            LoadSeg() (in this case __BSS_LEN could be 0)
  59.         ;
  60.         ;   COMPILER:
  61.         ;
  62.         ;   * If -r option specified when compiling then the compiler
  63.         ;     will generate autoinit code to handle data initialization
  64.         ;     that would otherwise require a reloc32 hunk.
  65.         ;
  66.         ;   * If -r or -md specified compiler references all data items
  67.         ;     using A4-Relative addressing.
  68.         ;
  69.         ;   C LIB CODE:
  70.         ;
  71.         ;   * Resident: Allocate (__DATA_LEN+__BSS_LEN)*4
  72.         ;     Not Res : zero out preallocated BSS.
  73.         ;
  74.         ;   * Generate A4 ref ptr to bss base + 32766 (uses Aztec's
  75.         ;     conventions).
  76.         ;
  77.         ;   * All library code uses the SMALL-DATA with alternate
  78.         ;     BSS and DATA section names (based in this source
  79.         ;     file) so the linker puts library related data/bss
  80.         ;     first.  BUT, BSS always comes after DATA unless
  81.         ;     you -frag the link (can't resident a frag'd link),
  82.         ;     so if there is more than 64KBytes of *initialized*
  83.         ;     data you must -frag the link.
  84.  
  85.         section text,code
  86.  
  87.         xref    __RESIDENT        ; (dlink), executable is residentable
  88.         xref    __BSS_LEN        ; (dlink), length of BSS
  89.         xref    __DATA_BAS        ; (dlink), base of initialized data
  90.         xref    __DATA_LEN        ; (dlink), length of data
  91.  
  92.         xref    _messydoshandler    ; we call messydoshandler()
  93.  
  94.         xref    _LVOSetSignal
  95.         xref    _LVOAllocMem
  96.         xref    _LVOFreeMem
  97.         xref    _LVOForbid
  98.         xref    _LVOReplyMsg
  99.  
  100.         xdef    _exit            ; we are exit()
  101.         xdef    start
  102.         xdef    _SysBase        ; we export _SysBase
  103. ;        xdef    __WBMsg
  104.  
  105. MEMF_CLEAR    equ    $00000001
  106. MEMF_PUBLIC    equ    $00010000
  107.  
  108. start:
  109. ;        movem.l D2-D7/A2-A6,-(sp)
  110.  
  111.         move.l    4,A6            ; EXEC base
  112.  
  113.         move.l    sp,A2
  114. ;        move.l    A0,-(sp)            ; save arg for _main() call
  115. ;        move.l    D0,-(sp)            ; save arglen for _main() call
  116.  
  117.         ;   If we are flagged resident then there is NO BSS ALLOCATED
  118.         ;   If we are not flagged resident then BSS IS ALLOCATED AFTER DATA,
  119.         ;    BUT NOT CLEARED.
  120.  
  121.         ;ifne resident
  122.         move.w    #__RESIDENT,D0
  123.         beq    snotres
  124.  
  125.         ;   Allocate BSS+DATA space and then copy static data.
  126.  
  127.         move.l    #__BSS_LEN,D0
  128.         add.l    #__DATA_LEN,D0
  129.         asl.l    #2,D0            ; x4
  130.         addq.l    #8,D0            ; MemList header extra
  131.         move.l    D0,D5            ; D5 = #bytes
  132.         move.l    #MEMF_PUBLIC,D1
  133.         jsr    _LVOAllocMem(A6)
  134.         tst.l    D0
  135.         bne    alok
  136.         move.l    A2,sp
  137.         moveq.l #-1,D0
  138.         bra    exfail
  139.  
  140. alok        move.l    D0,A0
  141.         clr.l    (A0)+               ; MemList entry next ptr
  142.         move.l    D5,(A0)+            ; MemList entry #bytes
  143.         lea    32766(A0),A4        ; SET A4
  144.         lea    -8(A0),A3           ; A3 = MemList entry base
  145.                         ; can't copy to MemList(A4) yet
  146.  
  147.  
  148.         ;   Copy data to allocated copy
  149.  
  150.                         ; A0 = dst
  151.         lea    __DATA_BAS,A1        ; A1 = src
  152.         move.l    #__DATA_LEN,D0        ; D0 = long words
  153.         bra    bssent
  154. bsslop        move.l    (A1)+,(A0)+
  155. bssent        dbf    D0,bsslop
  156.         sub.l    #$10000,D0
  157.         bcc    bsslop
  158.         bra    clrbss
  159.         ;endc
  160.  
  161.  
  162.         ;   Not resident, BSS space has been allocated for us
  163.         ;   beyond the specified data, just load the base ptr
  164.  
  165. snotres     lea    __DATA_BAS,A4
  166.         lea    32766(A4),A4
  167.         sub.l    A3,A3
  168.  
  169. clrbss
  170.         ;   CLEAR BSS    &-32766(A4) + __DATA_LEN*4
  171.  
  172.         lea    -32766(A4),A0
  173.         move.l    #__DATA_LEN,D0
  174.         asl.l    #2,D0
  175.         add.l    D0,A0
  176.  
  177.         move.l    #__BSS_LEN,D0        ; longwords of bss
  178.         moveq.l #0,D1
  179.         bra    clrent
  180. clrlop        move.l    D1,(A0)+
  181. clrent        dbf    D0,clrlop
  182.         sub.l    #$10000,D0
  183.         bcc    clrlop
  184.  
  185.         ;ifne resident
  186.         move.l    A3,___MemList(A4)   ; memlist entry (if resident)
  187.         ;endc
  188.         move.l    A2,__ExitSP(A4)     ; sp to restore
  189.  
  190. ;        moveq.l #0,D0            ; new signals
  191. ;        move.l    #$1000,D1        ; signal mask
  192. ;        jsr    _LVOSetSignal(A6)   ; clear ^C
  193.  
  194.         move.l    A6,_SysBase(A4)     ; resident segment.
  195.  
  196.         ;   Return value of 0 indicates succcess.  Flags
  197.         ;   have been set.
  198.  
  199.         ;ifne resident
  200.         jsr    __AutoInit0        ; A6 has SYSBase
  201.         bne    xfail
  202. ;        pea    1.W            ; autoconfig loader
  203. ;        jsr    __AutoConfig        ; note, rt pulls stack
  204. ;        addq.l    #4,sp
  205.         jsr    __AutoInit1        ; A6 has SYSBase
  206.         bne    xfail
  207.         ;endc
  208.         jsr    _messydoshandler(PC)
  209.  
  210.         ;   fall through to low level exit... this avoids referencing
  211.         ;   exit() if the user overides messydoshandler().
  212.  
  213. xfail
  214.         clr.l    -(sp)
  215.         clr.l    -(sp)
  216.  
  217.         ;   _EXIT()
  218.         ;
  219.         ;   since entry uses malloc we must free any incidental memory
  220.         ;   at __exit instead of _exit.
  221.         ;
  222.         ;   ReplyMsg(_WBMsg) just before returning
  223.  
  224. _exit:
  225. ;        pea    -1.W
  226. ;        jsr    __AutoConfig        ; note, rt pulls stack
  227. ;        addq.l    #4,sp
  228.         move.l    _SysBase(A4),A6
  229.         ;ifne resident
  230.         jsr    __AutoExit1        ; A6 has SysBase
  231.         jsr    __AutoExit0        ; A6 has SysBase
  232.         ;endc
  233.  
  234.         move.l    __ExitSP(A4),A5     ; get sp... because we might free
  235.                         ; the space taken by the variable!
  236.  
  237. ;        move.l    __WBMsg(A4),D6      ; D6 = WBMsg if it exists
  238.  
  239.         ;ifne resident
  240.         move.l    ___MemList(A4),D0   ; free memory
  241.         beq    ex20
  242. ex10        move.l    D0,A2
  243.         move.l    (A2),A3             ; next...
  244.  
  245.         move.l    4(A2),D0            ; bytes
  246.         move.l    A2,A1            ; ptr
  247.         jsr    _LVOFreeMem(A6)
  248.  
  249.         move.l    A3,D0            ; next...
  250.         bne    ex10
  251.         ;endc
  252. ex20
  253.  
  254.         move.l    4(sp),D0            ; get exit code
  255.         move.l    A5,sp            ; restore sp
  256.  
  257. ;        tst.l    D6            ; reply to workbench msg if it
  258. ;        beq    ex30            ; exists
  259. ;        jsr    _LVOForbid(A6)      ; forbid through exit
  260. ;        move.l    D6,A1
  261. ;        jsr    _LVOReplyMsg(A6)
  262.  
  263. ex30
  264.         ;   FINIS, poof.
  265.  
  266. exfail
  267. ;        movem.l (sp)+,D2-D7/A2-A6
  268.         rts
  269.  
  270.  
  271.         ;   Base of autoinit section
  272.  
  273.         ;ifne resident
  274.         section autoinit0,code
  275. __AutoInit0:
  276.         section autoinit1,code
  277. __AutoInit1:
  278.         section autoexit0,code
  279. __AutoExit0:
  280.         section autoexit1,code
  281. __AutoExit1:
  282.         ;endc
  283. ;        section autoconfig,code
  284. ;__AutoConfig:
  285.  
  286.  
  287.         ;   All library C code is compiled with the -S option
  288.         ;   which uses 'libdata' and 'libbss' section names,
  289.         ;   forcing library data to come before program data
  290.         ;   and library bss to come before program bss (because
  291.         ;   library data/bss sections are declared here first
  292.         ;   and sections of like name are coagulated).
  293.  
  294.         section libdata,data
  295. _Reserved    dc.l    0        ; force section to exist (dummy)
  296.  
  297.         section libbss,bss
  298.  
  299. _SysBase    ds.l    1
  300. __ExitSP    ds.l    1
  301. ;__WBMsg    ds.l    1
  302.         ;ifne resident
  303.         xdef    ___MemList    ; used by malloc/free
  304. ___MemList    ds.l    1
  305.         ;endc
  306.  
  307. ;;;;
  308. ;
  309. ; Some byte-swapping routines for extra bonus points.
  310. ;
  311. ; word Get8086Word(A0 byte *Word8086);
  312. ; word OtherEndianWord(D0 long oew);    /* long should become word */
  313. ; ulong OtherEndianLong(D0 ulong oel);
  314. ;
  315.  
  316.     section text,code
  317.  
  318.     xdef _Get8086Word
  319.     xdef @Get8086Word
  320. _Get8086Word:
  321.     move.l    4(sp),a0        ; get (unaligned) address
  322. @Get8086Word:
  323.     move.b    (a0)+,d1        ; get low order byte
  324.     move.b    (a0),d0         ; get high order byte
  325.     asl.w    #8,d0        ; shift it into position
  326.     move.b    d1,d0        ; put in the low order byte
  327.     rts
  328.  
  329.     xdef _OtherEndianWord
  330.     xdef @OtherEndianWord
  331. _OtherEndianWord:
  332.     move.w    4+2(sp),d0      ; arg is passed as a long for now
  333. @OtherEndianWord:
  334.     rol.w    #8,d0
  335.     rts            ; we leave junk in the high word of d0.
  336.  
  337.     xdef _OtherEndianLong
  338.     xdef @OtherEndianLong
  339. _OtherEndianLong:
  340.     move.l    4(sp),d0
  341. @OtherEndianLong:
  342.     rol.w    #8,d0
  343.     swap    d0
  344.     rol.w    #8,d0
  345.     rts
  346.  
  347. ;;;;
  348. ;
  349. ; Glue for the disk change interrupt handler. A4 is now in A1 (is_Data).
  350. ; We only need this when we compile for PURE code, but it won't harm
  351. ; either.
  352.  
  353.     xref _ChangeIntHand
  354.     xdef _ChangeIntHand0
  355. _ChangeIntHand0:
  356.     move.l    a4,-(sp)
  357.     movea.l a1,a4
  358.     jsr    _ChangeIntHand    ; C code
  359.     move.l    (sp)+,a4
  360.     rts
  361.  
  362.         ;   BeginIO(ior)
  363.  
  364.         section text,code
  365.  
  366.         xdef    _hyper_BeginIO
  367.         xdef    _BeginIO
  368.         xdef    @BeginIO
  369.  
  370. _hyper_BeginIO:
  371. _BeginIO:
  372.         move.l    4(sp),A0
  373. @BeginIO:
  374.         move.l    A6,-(sp)
  375.         move.l    A0,A1
  376.         move.l    $14(A0),A6   ; io_Device
  377.         jsr    -30(A6)
  378.         move.l    (sp)+,A6
  379.         rts
  380.  
  381.     END
  382.